feat: add section for unsupported packages to report

Author: Defelo

.github/workflows/review.yml

@@ -134,6 +134,7 @@ jobs:
         with:
           sparse-checkout: |
             .github/actions
+            drv-build-support.nix
             flake.lock
             flake.nix
             generate_markdown_report.py
@@ -181,6 +182,27 @@ jobs:
 
           report_json=~/.cache/nixpkgs-review/pr-${PR_NUMBER}/report.json
           report_md=~/.cache/nixpkgs-review/pr-${PR_NUMBER}/report.md
+
+          if failed=$(jq -er '.result[].failed[]' "$report_json"); then
+            git fetch origin "$MERGE" && git switch -d "$MERGE"
+            tmp=$(mktemp -d)
+            nix config show --json > "$tmp/nix-config.json"
+            nix derivation show --recursive -f. $failed > "$tmp/drv-graph.json"
+            nix-instantiate --eval --strict --json ../drv-build-support.nix \
+              --argstr configPath "$tmp/nix-config.json" \
+              --argstr drvGraphPath "$tmp/drv-graph.json" \
+              > "$tmp/drv-build-support.json"
+
+            for pkg in $failed; do
+              drvPath=$(nix eval -f. "${pkg}.drvPath" --raw)
+              drv=$(basename "$drvPath")
+              supported=$(jq '.[$drv].supported' "$tmp/drv-build-support.json" --arg drv "$drv")
+              if [[ "$supported" = "false" ]]; then
+                jq '.result[].failed -= [$pkg] | .result[].unsupported += [$pkg]' --arg pkg "$pkg" "$report_json" | sponge "$report_json"
+              fi
+            done
+          fi
+
           if failed=$(jq -er '.result[].failed[]' "$report_json"); then
             git fetch origin "$BASE" && git switch -d "$BASE"
             build=()
@@ -210,6 +232,7 @@ jobs:
           PR_JSON: ${{ needs.prepare.outputs.pr }}
           BASE: ${{ needs.prepare.outputs.base }}
           BASE_REF: ${{ needs.prepare.outputs.base_ref }}
+          MERGE: ${{ needs.prepare.outputs.merge }}
 
       - name: push results to cache
         if: ${{ inputs.push-to-cache && ((vars.ATTIC_SERVER != '' && vars.ATTIC_CACHE != '') || vars.CACHIX_CACHE != '') }}

drv-build-support.nix

@@ -0,0 +1,61 @@
+{ configPath, drvGraphPath }:
+
+let
+  importJSON = path: builtins.fromJSON (builtins.readFile path);
+  pipe = builtins.foldl' (acc: f: f acc);
+  flip =
+    f: x: y:
+    f y x;
+  unique = flip pipe [
+    (map (x: {
+      name = x;
+      value = null;
+    }))
+    builtins.listToAttrs
+    builtins.attrNames
+  ];
+
+  config = builtins.mapAttrs (_: { value, ... }: value) (importJSON configPath);
+  graph = importJSON drvGraphPath;
+
+  systems = [ config.system ] ++ config.extra-platforms;
+  features = config.system-features;
+
+  toList =
+    x:
+    if builtins.isList x then
+      x
+    else if builtins.isString x then
+      pipe x [
+        (builtins.split "([^[:space:]]+)")
+        (builtins.filter builtins.isList)
+        (map builtins.head)
+      ]
+    else
+      [ ];
+
+  requiredFeatures =
+    drv:
+    pipe
+      [
+        drv.env or { }
+        drv.structuredAttrs or { }
+      ]
+      [
+        (builtins.concatMap (x: toList x.requiredSystemFeatures or [ ]))
+        unique
+      ];
+
+  result = builtins.mapAttrs (_: drv: rec {
+    inherit (drv) system;
+    requiredSystemFeatures = requiredFeatures drv;
+    systemSupported = system == "builtin" || builtins.elem system systems;
+    featuresSupported = builtins.all (flip builtins.elem features) requiredSystemFeatures;
+    dependenciesSupported = builtins.all (drvPath: result.${drvPath}.supported) (
+      builtins.attrNames drv.inputDrvs
+    );
+    supported = systemSupported && featuresSupported && dependenciesSupported;
+  }) graph;
+in
+
+result

generate_markdown_report.py

@@ -38,5 +38,6 @@ def html_pkgs_section(emoji: str, packages: list[str], msg: str, what: str = "pa
     msg += html_pkgs_section(":x:", report.get("still_failing", []), f"still failing to build (also failed on {base})")
     msg += html_pkgs_section(":white_check_mark:", report["tests"], "built", what="test")
     msg += html_pkgs_section(":white_check_mark:", report["built"], "built")
+    msg += html_pkgs_section(":grey_question:", report.get("unsupported", []), "not supported by the current system")
 
 print(msg, end="")