Sprinkles/project.nix at release · FreshlyBakedCake/Sprinkles · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
# SPDX-FileCopyrightText: 2025 FreshlyBakedCake
#
# SPDX-License-Identifier: MIT

{
  pins,
  config,
  lib,
}:
{
  config = {
    name = "sprinkles";

    packages.sprinkles = {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      package =
        {
          fenix,
          makeRustPlatform,
          lib,
          installShellFiles,
          dbus,
          ...
        }:
        let
          toolchain = fenix.complete.toolchain;

          manifest = (lib.importTOML ./Cargo.toml).package;

          platform = makeRustPlatform {
            cargo = toolchain;
            rustc = toolchain;
          };
        in
        platform.buildRustPackage {
          meta.mainProgram = "sprinkles";
          pname = manifest.name;
          version = manifest.version;

          src = ./.;

          buildInputs = [ dbus ];
          nativeBuildInputs = [ installShellFiles ];

          cargoLock.lockFile = ./Cargo.lock;
        };
    };

    shells.sprinkles = {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      shell =
        {
          mkShell,
          kdePackages,
          fenix,
          bacon,
          pkg-config,
          reuse,
          dbus,
          sqlx-cli,
          system,
          ...
        }:
        mkShell {
          QML_IMPORT_PATH =
            lib.fp.pipe
              [
                (map (pkg: "${pkg}/lib/qt-6/qml"))
                (builtins.concatStringsSep ":")
              ]
              [
                (config.inputs.quickshell.result.packages.${system}.default.override {
                  gitRev = pins.quickshell.revision;
                })
                kdePackages.qtdeclarative
              ];

          buildInputs = [ dbus ];
          packages = [
            kdePackages.qtdeclarative
            (fenix.complete.withComponents [
              "cargo"
              "clippy"
              "rust-src"
              "rustc"
              "rustfmt"
              "rust-analyzer"
            ])
            sqlx-cli
            bacon
            pkg-config
            reuse
            dbus
          ];
        };
    };

    shells.sprinkles-testing = {
      systems = [
        "x86_64-linux"
        "aarch64-linux"
      ];

      shell =
        {
          mkShell,
          libnotify,
          sqlitebrowser,
          system,
          ...
        }:
        mkShell {
          buildInputs = [ libnotify ];
          packages = [
            libnotify
            sqlitebrowser
            config.packages.sprinkles.result.${system}
            (config.inputs.quickshell.result.packages.${system}.default.override {
              gitRev = pins.quickshell.revision;
            })
          ];
        };
    };
  };
}