time12: init at 1.2.2

Author: mrtnvgr

pkgs/by-name/ti/time12/package.nix

@@ -0,0 +1,152 @@
+{
+  stdenv,
+  lib,
+  fetchFromGitHub,
+  nix-update-script,
+  cmake,
+  pkg-config,
+  writableTmpDirAsHomeHook,
+  libx11,
+  libxrandr,
+  libxinerama,
+  libxext,
+  libxcursor,
+  libxtst,
+  freetype,
+  fontconfig,
+  webkitgtk_4_1,
+  curl,
+  alsa-lib,
+  libsysprof-capture,
+  pcre2,
+  util-linux,
+  libselinux,
+  libsepol,
+  libthai,
+  libdatrie,
+  libxdmcp,
+  libdeflate,
+  lerc,
+  xz,
+  libwebp,
+  libxkbcommon,
+  libepoxy,
+  sqlite,
+
+  buildStandalone ? true,
+  buildVST3 ? true,
+  buildLV2 ? true,
+}:
+stdenv.mkDerivation (finalAttrs: {
+  name = "time12";
+  version = "1.2.2";
+
+  src = fetchFromGitHub {
+    owner = "tiagolr";
+    repo = "time12";
+    tag = "v${finalAttrs.version}";
+    fetchSubmodules = true;
+    hash = "sha256-kyh1IMiOykkSglpuJo2DnNOluUdO38Z25ONXh0mi400=";
+  };
+
+  nativeBuildInputs = [
+    cmake
+    pkg-config
+    writableTmpDirAsHomeHook
+  ];
+
+  buildInputs = [
+    libx11
+    libxrandr
+    libxinerama
+    libxext
+    libxcursor
+    libxtst
+    freetype
+    fontconfig
+    webkitgtk_4_1
+    curl
+    alsa-lib
+    libsysprof-capture
+    pcre2
+    util-linux
+    libselinux
+    libsepol
+    libthai
+    libdatrie
+    libxdmcp
+    libdeflate
+    lerc
+    xz
+    libwebp
+    libxkbcommon
+    libepoxy
+    sqlite
+  ];
+
+  # JUCE dlopens these at runtime, standalone executable crashes without them
+  NIX_LDFLAGS = [
+    "-lX11"
+    "-lXext"
+    "-lXcomposite"
+    "-lXcursor"
+    "-lXinerama"
+    "-lXrandr"
+    "-lXrender"
+    "-lXtst"
+    "-lXdmcp"
+  ];
+
+  # Fontconfig error: Cannot load default config file: No such file: (null)
+  env.FONTCONFIG_FILE = "${fontconfig.out}/etc/fonts/fonts.conf";
+
+  postPatch = ''
+    substituteInPlace CMakeLists.txt \
+      --replace-fail "juce::juce_recommended_lto_flags" "# Not forcing LTO"
+
+    substituteInPlace CMakeLists.txt \
+      --replace-fail "COPY_PLUGIN_AFTER_BUILD TRUE" "COPY_PLUGIN_AFTER_BUILD FALSE"
+  '';
+
+  cmakeFlags = [
+    (lib.cmakeFeature "CMAKE_AR" (lib.getExe' stdenv.cc.cc "gcc-ar"))
+    (lib.cmakeFeature "CMAKE_RANLIB" (lib.getExe' stdenv.cc.cc "gcc-ranlib"))
+
+    (lib.cmakeBool "BUILD_STANDALONE" buildStandalone)
+    (lib.cmakeBool "BUILD_VST3" buildVST3)
+    (lib.cmakeBool "BUILD_LV2" buildLV2)
+  ];
+
+  installPhase = ''
+    runHook preInstall
+
+    pushd TIME12_artefacts/Release
+      ${lib.optionalString buildStandalone ''
+        install -Dm755 Standalone/TIME-12 -t $out/bin
+      ''}
+
+      ${lib.optionalString buildVST3 ''
+        mkdir -p $out/lib/vst3
+        cp -r VST3/TIME-12.vst3 $out/lib/vst3
+      ''}
+
+      ${lib.optionalString buildLV2 ''
+        mkdir -p $out/lib/lv2
+        cp -r LV2/TIME-12.lv2 $out/lib/lv2
+      ''}
+    popd
+
+    runHook postInstall
+  '';
+
+  passthru.updateScript = nix-update-script { };
+
+  meta = {
+    description = "Envelope based delay modulator";
+    homepage = "https://github.com/tiagolr/time12";
+    platforms = [ "x86_64-linux" ];
+    license = lib.licenses.gpl3Plus;
+    maintainers = [ lib.maintainers.mrtnvgr ];
+    mainProgram = lib.optionalString buildStandalone "TIME-12";
+  };
+})