nixos/meshtasticd: init

Author: drupol

nixos/modules/module-list.nix

@@ -1242,6 +1242,7 @@
   ./services/networking/lxd-image-server.nix
   ./services/networking/magic-wormhole-mailbox-server.nix
   ./services/networking/matterbridge.nix
+  ./services/networking/meshtasticd.nix
   ./services/networking/microsocks.nix
   ./services/networking/mihomo.nix
   ./services/networking/minidlna.nix

nixos/modules/services/networking/meshtasticd.nix

@@ -0,0 +1,66 @@
+{
+  config,
+  lib,
+  pkgs,
+  ...
+}:
+
+let
+  cfg = config.services.meshtasticd;
+  format = pkgs.formats.yaml { };
+  configFile = format.generate "config.yaml" cfg.settings;
+in
+{
+  options.services.meshtasticd = {
+    enable = lib.mkEnableOption "Meshtastic daemon";
+    package = lib.mkPackageOption pkgs "meshtasticd" { };
+
+    port = lib.mkOption {
+      type = lib.types.port;
+      default = 4403;
+      description = "Port to listen on";
+    };
+
+    settings = lib.mkOption {
+      type = format.type;
+      description = ''
+        TODO
+      '';
+    };
+
+    dataDir = lib.mkOption {
+      default = "/var/lib/meshtasticd";
+      type = lib.types.path;
+      description = ''
+        The data directory.
+      '';
+    };
+
+  };
+
+  config = lib.mkIf cfg.enable {
+    systemd.services.meshtasticd = {
+      description = "Meshtastic daemon";
+      after = [
+        "network-online.target"
+        "network.target"
+      ];
+      wants = [
+        "network-online.target"
+        "network.target"
+      ];
+      wantedBy = [ "multi-user.target" ];
+
+      serviceConfig = {
+        DynamicUser = true;
+        StateDirectory = "meshtasticd";
+        AmbientCapabilities = [
+          "CAP_NET_BIND_SERVICE"
+        ];
+        ExecStart = "${lib.getExe cfg.package} --port=${builtins.toString cfg.port} --fsdir=${cfg.dataDir} --config=${configFile} --verbose";
+        Restart = "always";
+        RestartSec = "3";
+      };
+    };
+  };
+}

nixos/tests/all-tests.nix

@@ -937,6 +937,7 @@ in
   meilisearch = runTest ./meilisearch.nix;
   memcached = runTest ./memcached.nix;
   merecat = runTest ./merecat.nix;
+  meshtasticd = runTest ./networking/meshtasticd.nix;
   metabase = runTest ./metabase.nix;
   mihomo = runTest ./mihomo.nix;
   mimir = runTest ./mimir.nix;

nixos/tests/networking/meshtasticd.nix

@@ -0,0 +1,44 @@
+{
+  lib,
+  pkgs,
+  ...
+}:
+let
+  mainPort = 9445;
+  webPort = 9446;
+in
+{
+  name = "meshtasticd";
+  meta.maintainers = [ lib.maintainers.drupol ];
+
+  nodes.machine = {
+    services.meshtasticd = {
+      enable = true;
+      port = mainPort;
+
+      settings = {
+        Lora = {
+          Module = "sim";
+          DIO2_AS_RF_SWITCH = false;
+          spiSpeed = "2000000";
+        };
+        Webserver = {
+          Port = webPort;
+          RootPath = pkgs.meshtastic-web;
+        };
+        General = {
+          MaxNodes = 200;
+          MaxMessageQueue = 100;
+          MACAddressSource = "eth0";
+        };
+      };
+    };
+  };
+
+  testScript = ''
+    with subtest("Test meshtasticd service"):
+      machine.wait_for_unit("meshtasticd.service")
+      machine.wait_for_open_port(${builtins.toString mainPort})
+      machine.wait_for_open_port(${builtins.toString webPort})
+  '';
+}