sceneview/build.gradle at main · sceneview/sceneview · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
plugins {
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.android.application) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.compose.compiler) apply false
    alias(libs.plugins.compose.multiplatform) apply false
    alias(libs.plugins.dokka) apply false
    alias(libs.plugins.publish) apply false
    alias(libs.plugins.detekt) apply false
}

// Force patched versions of transitive npm dependencies (Dependabot security alerts)
plugins.withType(org.jetbrains.kotlin.gradle.targets.js.yarn.YarnPlugin) {
    extensions.getByType(org.jetbrains.kotlin.gradle.targets.js.yarn.YarnRootExtension).tap {
        resolution("serialize-javascript", ">=7.0.3")
        resolution("webpack", ">=5.104.1")
        resolution("webpack-dev-server", ">=5.2.1")
        resolution("path-to-regexp", ">=0.2.2")
        resolution("brace-expansion", ">=1.1.13")
    }
}

subprojects {
    plugins.withId("com.vanniktech.maven.publish") {
        mavenPublishing {
            publishToMavenCentral()
            signAllPublications()
        }
    }

    // Apply detekt to all subprojects that use Kotlin
    plugins.withId("org.jetbrains.kotlin.android") {
        apply plugin: "io.gitlab.arturbosch.detekt"
        detekt {
            buildUponDefaultConfig = true
            config.setFrom(rootProject.files("buildSrc/config/detekt/detekt.yml"))
            parallel = true
        }
    }
    plugins.withId("org.jetbrains.kotlin.multiplatform") {
        apply plugin: "io.gitlab.arturbosch.detekt"
        detekt {
            buildUponDefaultConfig = true
            config.setFrom(rootProject.files("buildSrc/config/detekt/detekt.yml"))
            parallel = true
        }
    }
}