build: replace bash/bat for stdout->stderr wrapping

Simpler code and no system dependencies.

Author: SamWindell

src/build/std_extras.zig

@@ -182,45 +182,21 @@ pub fn createCommandWithStdoutToStderr(
     target: ?std.Target,
     name: []const u8,
 ) *std.Build.Step.Run {
-    const run = std.Build.Step.Run.create(b, name);
-
-    // IMPROVE: it would probably be more robust to create a small Zig program (like fetch()) that does this
-    // redirection so we can guarantee cross-platform compatibility and don't have to do the bash vs batch stuff.
-
-    if (builtin.os.tag == .windows) {
-        const batch_wrapper = b.addWriteFiles().add("stdout-to-stderr-wrapper.bat",
-            \\@echo off
-            \\%* 1>&2
-            \\exit /b %errorlevel%
-        );
-        run.addFileArg(batch_wrapper);
-    } else {
-        const bash_wrapper = b.addWriteFiles().add("stdout-to-stderr-wrapper.sh",
-            \\#!/usr/bin/env bash
-            \\exec "$@" >&2
-        );
-        if (target != null and target.?.os.tag == .windows) {
-            if (builtin.os.tag == .linux and b.enable_wine) {
-                run.addArg("bash");
-                run.addFileArg(bash_wrapper);
-                run.addArg("wine64");
-            } else {
-                // It's probably not going to work, but we can try natively. At any rate, we are deferring the
-                // error to later when the actual command is run (which might never happen).
-                run.addArg("bash");
-                run.addFileArg(bash_wrapper);
-            }
-        } else {
-            // macOS or Linux - use system pluginval
-            run.addArg("bash");
-            run.addFileArg(bash_wrapper);
-        }
+    const run = b.addRunArtifact(b.addExecutable(.{
+        .name = name,
+        .root_module = b.createModule(.{
+            .root_source_file = b.path("src/build/wrap_stdout_to_stderr_cmd.zig"),
+            .target = b.graph.host,
+        }),
+    }));
+
+    if (builtin.os.tag == .linux and b.enable_wine and target != null and target.?.os.tag == .windows) {
+        run.addArg("wine64");
     }
 
     return run;
 }
 
-
 // A wrapper for turning commands that modify files in-place into commands with input and output files.
 // See wrap_inplace_cmd.zig for more information.
 // To use it, create the InPlaceCmd, add args as normal to the .run field, but at some point you must call

src/build/wrap_stdout_to_stderr_cmd.zig

@@ -0,0 +1,40 @@
+// Copyright 2025 Sam Windell
+// SPDX-License-Identifier: GPL-3.0-or-later
+
+// Little util that wraps a command and redirects its stdout to stderr.
+
+// Why this exists:
+// In the Zig build system when using std.Build.Step.Run, Zig never prints stdout to the console, only stderr.
+// If the program doesn't put debug information in stderr, you don't see anything other than the exit code.
+// This wrapper redirects stdout to stderr so you see all output, allowing you to debug why a program fails.
+
+const builtin = @import("builtin");
+const std = @import("std");
+
+pub fn main() !u8 {
+    var arena = std.heap.ArenaAllocator.init(std.heap.page_allocator);
+    const allocator = arena.allocator();
+    var args = try std.process.argsAlloc(allocator);
+
+    std.debug.assert(args.len >= 2);
+
+    const result = try std.process.Child.run(.{
+        .allocator = allocator,
+        .argv = args[1..],
+    });
+
+    // Redirect stdout to stderr
+    if (result.stdout.len > 0) std.io.getStdErr().writer().writeAll(result.stdout) catch {};
+    if (result.stderr.len > 0) std.io.getStdErr().writer().writeAll(result.stderr) catch {};
+
+    switch (result.term) {
+        .Exited => |code| {
+            return code;
+        },
+        .Signal, .Stopped, .Unknown => {
+            std.io.getStdErr().writer().writeAll("terminated unexpectedly\n") catch {};
+            return 1;
+        },
+    }
+}
+