tech-debt/build.gradle.kts at main · igorescodro/tech-debt · GitHub

1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
plugins {
    alias(libs.plugins.kotlin.jvm) apply false
    alias(libs.plugins.kotlin.multiplatform) apply false
    alias(libs.plugins.kotlin.android) apply false
    alias(libs.plugins.android.library) apply false
    alias(libs.plugins.ksp) apply false
    alias(libs.plugins.maven.publish) apply false
    alias(libs.plugins.detekt)
    alias(libs.plugins.ktfmt)
    id("lifecycle-base")
}

repositories {
    mavenLocal()
    mavenCentral()
    google()
}

subprojects {
    apply(plugin = "io.gitlab.arturbosch.detekt")
    apply(plugin = "com.ncorti.ktfmt.gradle")

    detekt {
        buildUponDefaultConfig = true
        allRules = false
        config.setFrom(files("$rootDir/config/detekt/detekt.yml"))
    }

    ktfmt {
        kotlinLangStyle()
    }
}

val test by tasks.registering {
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":test"))
    subprojects.forEach { subproject ->
        dependsOn(subproject.tasks.matching { it.name == "test" })
    }
}

tasks.named("check") {
    dependsOn(test)
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":check"))
}

tasks.named("build") {
    dependsOn(test)
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":build"))
}

tasks.named("ktfmtCheck") {
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":ktfmtCheck"))
}

tasks.named("ktfmtFormat") {
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":ktfmtFormat"))
}

tasks.named("detekt") {
    dependsOn(gradle.includedBuild("techdebt-gradle-plugin").task(":detekt"))
}